// genesis -- tutorial 8 -- net_conn.g

// connection setup for eight queens problem

// Excitatory connections between input "cells" and network cells;
// note that the same synchan receives input from external inputs
// as well as from cells in the network.  Note also that each
// input randomspike element only connects to one cell in the network,
// since the range of excitation for the destination cells is so 
// narrow.
 
planarconnect /in/input[] /network/cell[]/dend/Ex_channel  \
        -relative                                \
        -sourcemask box -1 -1 1 1                \  // all cells
        -destmask   box -0.01 -0.01 0.01 0.01       // very narrow excitatory range

planarweight /in/input[] -fixed 5.0 
 
// set axonal/synaptic delays to zero; this is not very biological
planardelay  /in/input[] -fixed 0.0

// inhibitory connections between network cells:

// 1) Horizontal:
planarconnect  /network/cell[]/soma/spike      \
	/network/cell[]/soma/Inh_channel       \
	-relative                              \
	-sourcemask box	-10 -10 10 10          \  // all cells
	-destmask   box	-0.01 -10 0.01 10      \  // horizontal line of connections
	-desthole   box -0.01 -0.01 0.01 0.01     // don't allow cells to connect to
						  // themselves

// 2) Vertical:
planarconnect  /network/cell[]/soma/spike      \
	/network/cell[]/soma/Inh_channel       \
	-relative                              \
	-sourcemask box	-10 -10 10 10          \  // all cells
	-destmask   box -10 -0.01 10 0.01      \  // vertical line of connections
	-desthole   box -0.01 -0.01 0.01 0.01     // don't allow cells to connect to
						  // themselves

// 3) Diagonal; these are a pain!
int   dist 
float tiny = 0.0001
 
for (dist = 1; dist < 8; dist = dist + 1)
    planarconnect /network/cell[]/soma/spike                      \
        /network/cell[]/soma/Inh_channel                         \
        -relative                                                \
        -sourcemask box -10 -10 10 10                            \ // all cells
        -destmask box  {-0.1 * dist - tiny} {-0.1 * dist - tiny} \
                       {-0.1 * dist + tiny} {-0.1 * dist + tiny} \ 
        -destmask box  {-0.1 * dist - tiny} { 0.1 * dist - tiny} \
                       {-0.1 * dist + tiny} { 0.1 * dist + tiny} \
        -destmask box  { 0.1 * dist - tiny} {-0.1 * dist - tiny} \
                       { 0.1 * dist + tiny} {-0.1 * dist + tiny} \ 
        -destmask box  { 0.1 * dist - tiny} { 0.1 * dist - tiny} \
                       { 0.1 * dist + tiny} { 0.1 * dist + tiny} 
end

planarweight /network/cell[]/soma/spike -fixed 15.0

// set axonal/synaptic delays to zero; this is not very biological
planardelay  /network/cell[]/soma/spike -fixed 0.0